Statement keywords appear in uppercase letters in the syntax rules. Some statement keywords identify the statement, such as in the following DO statement:

DO I = 1, 10

DO is a statement keyword that identifies the DO statement. Other keywords identify parts of a statement such as ONLY in a USE statement or WHILE in one of the forms of a DO construct, as follows:

DO WHILE( .NOT. FOUND )

Others specify options in the statement such as IN, OUT, or INOUT in the INTENT statement.

There are three statements in Fortran that have no statement keyword. They are the assignment statement, the pointer assignment statement, and the statement function.

Some sequences of capital letters in the formal syntax rules are not statement keywords. For example, EQ, in the lexical token .EQ., and EN, as an edit descriptor, are not statement keywords.

A dummy argument keyword, a different sort of keyword, is discussed in the Fortran Language Reference Manual, Volume 2.

Variables, named constants, program units, common blocks, procedures, arguments, constructs, derived types (types for structures), namelist groups, structure components, dummy arguments, and function results are among the elements in a program that have a name. Fortran permits up to 31 characters in a name.

_

$

A name must begin with a letter and can consist of letters, digits, and underscores. The CF90 and MIPSpro 7 Fortran 90 compilers allow you to use the underscore (_), at sign (@), and dollar sign ($) in a name, but none of these can be the first character of a name. Use of @ and $ is not recommended, however, because these are intended for internal use.

The following are examples of names:

A
CAR_STOCK_NUMBER
A__BUTTERFLY
Z_28
TEMP_

---

Note: The Fortran standard does not allow the dollar sign ($) or the at sign (@) character in a name. The at sign (@) is not included in the standard character set.

---

---

Note: : The MIPSpro 7 Fortran 90 compiler does not support the at sign (@).

---

A constant is a syntactic notation for a value. The value can be of any intrinsic type; that is, it can be a numeric (integer, real, or complex) value, a character value, or a logical value. A constant is defined as follows:

The following notes pertain to the preceding format:

A value that does not have a name is a literal constant. The following are examples of literal constants:

1.23
400
( 0.0, 1.0 )
"ABC"
B'0110110'
.TRUE.

The BOZ constants are described in “Format for Constant Values” in Chapter 4.

No literal constant can be array-valued or of derived type. “Intrinsic Data Types” in Chapter 4 describes the formats of literal constants in more detail.

A value that has a name is called a named constant and can be of any type, including a derived type. A named constant can also be array-valued. In the following statements, X_AXIS and MY_SPOUSE are examples of named constants:

REAL, DIMENSION(2), PARAMETER :: X_AXIS = (/ 0.0, 1.0 /)
TYPE(PERSON), PARAMETER :: MY_SPOUSE = PERSON( 39, 'PAT' )

Note that the entity on the right of the equal sign is not itself a constant but a constant expression. The forms for defining named constants are described in more detail in “PARAMETER Attribute and Statement” in Chapter 5.

Operators are used with operands in expressions to produce other values. The following are examples of intrinsic operators:

The intrinsic_operators are defined as follows:

power_op

mult_op

add_op

concat_op

rel_op

not_op

and_op

or_op

equiv_op

**

*

/

+

-

//

.EQ.

.NE.

.LT.

.LE.

.GT.

.GE.

.LG.

==

/=

<

<=

>

>=

<>

.NOT.

.N.

.AND.

.A.

.OR.

.O.

.EQV.

.NEQV.

.XOR.

.X.

The abbreviations .A., .O., .N., and .X. are synonyms for .AND., .OR., .NOT., and .XOR., respectively. If the abbreviated operator is overloaded in an interface block as a defined operator, the abbreviated form of the intrinsic operator cannot be used in any scope in which the defined operator is accessible.

---

Note: The Fortran standard does not specify the .A., .O., or .N., abbreviations for the logical operators, nor does it specify the .XOR. operator or its .X. abbreviation. The Fortran standard does not specify the .LG. or <> operators. You can define operators in addition to the intrinsic operators. User-defined operators begin with a period (.), followed by a sequence of up to 31 letters, and end with a period (.), except that the letter sequence must not be the same as any intrinsic operator defined by the Fortran standard or the logical constants .FALSE. or .TRUE.

---

A label can be used to identify a statement. A label consists of 1 to 5 decimal digits, one of which must be nonzero. If a statement has a label, it is uniquely identified and the label can be used in DO constructs, CALL statements, branching statements, and I/O statements.

Leading zeros in a label are not significant. In other words, the labels 020 and 20 are considered to be the same label. A statement label is local to a scoping unit. This means that a program unit can contain more than one definition of the same label as long as the labels are defined in different scoping units. For example, a main program and a contained internal subprogram can both define the same statement label. The cases in which duplicate labels can be used in the same program unit are explained as part of the general treatment of the scope of entities in the Fortran Language Reference Manual, Volume 2.

The following are examples of statements with labels:

100 CONTINUE
 21 X = X + 1.2
101 FORMAT (1X, 2F10.2)

Fortran syntax does not permit a statement with no content. This is sometimes referred to as a blank statement. Such a statement is always treated as a comment; therefore, if such a statement is created, it must not be labeled. For example, each of the following lines is nonstandard Fortran. They generate an error message from the CF90 and MIPSpro 7 Fortran 90 compilers:

10
X=0;101;

In free source form, the only restriction on statement positioning within a line is that the line itself cannot contain more than 132 characters. A blank character is significant and may be required to separate lexical tokens.

Blank characters are significant everywhere, but a sequence of blank characters outside a character context is treated as a single blank character. They can be used freely between tokens and delimiters to improve the readability of the source text. For example, the following two statements are interpreted identically:

SUM=SUM+A(I)
SUM = SUM + A (I)

Each line can contain from 0 through 132 characters.

The exclamation mark (!), not in character context, indicates the beginning of a comment that ends with the end of the line. A line can consist of nothing but a comment. Comments, including the !, are ignored and do not alter the interpretation of statements in any way.

The CF90 and MIPSpro 7 Fortran 90 compilers support compiler directives. Compiler directives are lines inserted into source code that specify actions to be performed by the compiler. Compilers other than the CF90 and MIPSpro 7 Fortran 90 compilers may treat compiler directive lines as comments. For more information on compiler directives, see the CF90 Commands and Directives Reference Manual, or the MIPSpro 7 Fortran 90 Commands and Directives Reference Manual.

A line whose first nonblank character is an exclamation mark is called a comment line.

The following is an example of a comment line:

! Begin the next iteration.

The following is an example of a statement with a trailing comment:

ITER = ITER + 1   ! Begin the next iteration.

An ampersand (&), not in a character context, is a continuation symbol and must be followed by one of the following:

The following is an example of a continued line and a continuation line:

FORCE = G * MASS1 *  & ! This is a continued line.
       MASS2 / R**2 ! This is a continuation line.

The CF90 and MIPSpro 7 Fortran 90 compilers allow a statement to be continued with up to 99 continuation lines.

---

Note: If you are using free source form, the Fortran standard allows no more than 39 continuation lines within a statement.

---

No line can contain an ampersand as the only nonblank character before an exclamation mark. Comment lines cannot be continued. That is, the ampersand as the last character in a comment is part of the comment and does not indicate continuation.

A line with only blank characters or with no characters is treated as a comment line.

More than one statement or partial statement can appear on a line. The statement separator is the semicolon (;), provided it is not in a character context. Multiple successive semicolons on a line with or without blanks intervening are considered as a single separator. The end of a line is also a statement separator, but a semicolon at the end of a line that is not part of a comment is considered as a single separator. Essentially, a null statement is a legal Fortran statement. The following statements show use of the semicolon:

! The semicolon is a statement separator.
X = 1.0;  Y = 2.0
! However, the semicolon below, at the end of a
! line, is not treated as a separator and is
! ignored.
Z = 3.0;
! Also, consecutive semicolons are treated as one
! semicolon, even if blanks intervene.
Z = 3.0; ; W = 4.0

A label can appear before a statement, provided that it is not part of another statement, but it must be separated from the statement by at least one blank. Examples:

10 FORMAT(10X,2I5)                ! 10 is a label
   IF (X == 0.0) 200 Y = SQRT(X)  ! Label 200 is
                                  ! not allowed.

Any printable character can be used in character literal constants and character string edit descriptors.

The CF90 and MIPSpro 7 Fortran 90 compilers support only the ASCII character set. The Fortran Language Reference Manual, Volume 3, describes the ASCII character set.

STOKES_LAW_VELOCITY = 2 * GRAVITY * RADIUS ** 2 *  &
      (DENSITY_1 - DENSITY_2) / (9 * COEFF_OF_VISCOSITY)

STOKES_LAW_VELOCITY = 2 * GRAVITY * RADIUS ** 2 * (DEN&
      &SITY_1 - DENSITY_2) / (9 * COEFF_OF_VISCOSITY)

LAWYERS = "Jones & Clay & &
&Davis"

Blanks As Separators

Blanks in free source form cannot appear within tokens, such as names or symbols consisting of more than 1 character, but blanks can be used freely in format specifications. For example, blanks cannot appear between the characters of multicharacter operators such as ** and .NE.. Format specifications are an exception because blanks can appear within edit descriptors such as BN, SS, or TR.

The CF90 and MIPSpro 7 Fortran 90 compilers treat tabs and single blanks as equivalent in free source form, except in character literal strings.

---

Note: The Fortran standard does not allow tabs in Fortran source files.

---

A blank must be used to separate a statement keyword, name, constant, or label from an adjacent name, constant, or label. For example, the blanks in the following statements are required:

INTEGER SIZE PRINT 10,N DO I=1,N

Adjacent keywords require a blank separator in some cases (for example, CASE DEFAULT). In other cases, two adjacent keywords can be written either with or without intervening blanks (for example, BLOCK DATA).

Blank separators are optional in the following keywords:

• BLOCK DATA

• DOUBLE PRECISION

• ELSE IF

• END BLOCK DATA

• END DO

• END FILE

• END IF

• END INTERFACE

• END MODULE

• END PROGRAM

• END SELECT

• END SUBROUTINE

• END TYPE

• END WHERE

• GO TO

• IN OUT

• SELECT CASE

Blank separators are mandatory in the following keywords:

• CASE DEFAULT

• DO WHILE

• IMPLICIT type_spec

• IMPLICIT NONE

• INTERFACE ASSIGNMENT

• INTERFACE OPERATOR

• MODULE PROCEDURE

• RECURSIVE FUNCTION

• RECURSIVE SUBROUTINE

• RECURSIVE type_spec

• type_spec FUNCTION

• type_spec RECURSIVE

Blanks are not mandatory in all cases, but blank separators between statement keywords make the source text more readable and clarify the statements. Generally, if common rules of English text are followed, everything will be correct. For example, blank separators in the following statements make them quite readable, and the blanks in DOUBLE PRECISION and END FUNCTION are optional:

RECURSIVE FUNCTION F(X) DOUBLE PRECISION X END FUNCTION F

 123456789.......
 -----------------------------------------------------
|PROGRAM LEFT_RIGHT
| REAL  X(5), Y(5)
|       ! Print arrays X and Y
|       PRINT 100, X, Y
|       100 FORMAT (F10.1, F10.2, F10.3, F10.4,  &
|                   F10.5)
|   . . .
|END

Fixed source form is position oriented on a line using the historical Fortran conventions for position that were used on punched cards.

---

Note: The Fortran standard has declared fixed source form to be obsolescent. The preferred alternative is free source form.

---

By default, statements or parts of statements must be written between positions 7 and 72, inclusive. The f90(1) command line includes options that allow you to specify different line lengths. For information on specifying different line lengths, see the CF90 Commands and Directives Reference Manual, or the MIPSpro 7 Fortran 90 Commands and Directives Reference Manual.

Regardless of the command line specification, character positions 1 through 6 are reserved for special purposes.

---

Note: The Fortran standard does not allow a compiler to recognize characters beyond column 72.

---

Blanks are not significant in fixed source form except in a character context. For example, the following two statements are identical:

D O  10  I = 1, L O O P E N D
DO 10 I = 1, LOOPEND

A C or * in position 1 identifies a comment. In this case, the entire line is a comment and is called a comment line. A ! in any position except position 6 and not in a character context indicates that a comment follows to the end of the line. Comments are not significant.

A line with only blank characters or with no characters is treated as a comment line.

Multiple statements on a line are separated by one or more semicolons. Semicolons can occur at the end of a line, and these are ignored.

Any character (including ! and ;) other than blank or 0 in position 6 indicates that the line is a continuation of the previous line. Such a line is called a continuation line. The text on the continuation line begins in position 7. There can be no more than 99 continuation lines for one statement in fixed source form. The first line of a continued statement is called the initial line.

---

Note: If you are using fixed source form, the Fortran standard allows no more than 19 continuation lines within a statement.

---

Statement labels can appear only in positions 1 through 5. A label can appear only on the initial line of a continued statement. Thus, positions 1 through 5 of continuation lines must contain blanks.

The CF90 and MIPSpro 7 Fortran 90 compilers allow you to continue an END statement, as follows:

 E
&N
&D

---

Note: The Fortran standard states that an END statement must not be continued.

---

The characters END can appear as the only characters on the initial line of a statement, as follows:

 END
&FILE(10)

---

Note: The Fortran standard states that END cannot be an initial line of a statement other than an END statement.

---

Any character from the CF90 and MIPSpro 7 Fortran 90 character set (including graphic and control characters) can be used in character literal constants and character edit descriptors. Although the Fortran standard permits a processor to limit the use of control characters (such as the newline) to such character contexts, the compilers impose no such limitation.

Tab Character

You can substitute the tab character for spaces at the beginning of a line, but it is not actually converted to spaces. The compiler uses the tab as follows:

• If a tab is the first character on a line, the next character determines how the line is interpreted. A nonzero digit indicates a continuation line. Otherwise, this line is the initial line of a statement.

• A statement label, if present, must precede the first tab.

• The compiler treats the tab character in a statement the same way it treats a blank character.

A tab character is not converted to spaces, so the exact visual placement of tabbed statements depends on the utility you use to edit or display text.

---

Note: : A tab counts as 1 character even though it may expand to more than one space in the listing or editor. Thus, statements that include tabs may appear to have data beyond column 72 (or 80) in the editor or listing.

---

 123456789.....
---------------------------------------------
|      PROGRAM LEFT_RIGHT
|      REAL  X(5), Y(5)
|C     Print arrays X and Y
|      PRINT 100, X, Y
|  100 FORMAT (F10.1, F10.2, F10.3, F10.4,
|     1        F10.5)
|         . . .
|      END

The following is a sample program that is acceptable in either fixed or free source form. Note that the numbers and the line at the top are not part of the program; the vertical bars to the left of the program are also not part of the program. These graphics are included to show the columns this program uses in fixed source form.

 123456789.....                                      73
 -------------------------------------------.....----
|      PROGRAM LEFT_RIGHT
|      REAL  X(5), Y(5)
|!     Print arrays X and Y
|      PRINT 100, X, Y
|  100 FORMAT (F10.1, F10.2, F10.3, F10.4,           &
|     &        F10.5)
|         . . .
|      END